!!! Objemový model struktury C pro lineární úlohu při zatížení ve směru osy x !!!

FINISH
/CLEAR

*ABBR,INPUT,'/INPUT,strukturaC_linear_X,txt'   
*AFUN,DEG 

/PREP7
 
*DO,step,1,8,1 		! cyklus pro automaticky vypocet
 
!!!!!!!!!!!!!!!!!!!
!!! PREPROCESOR !!!
!!!!!!!!!!!!!!!!!!!           
  
*AFUN,DEG
/PREP7

!!! Vstupni parametry !!!
alfa=55+(step-1)*5		! uhel alfa	[°]			
H=10					! delka H [mm]
LH=1.25					! pomer L/H [-]				
Emod=200000				! modul pruznosti v tahu zakladniho materialu [MPa]
nu=0.3					! Poissonuv pomer zakladniho materialu [-]
Fappl=-1				! zatezna sila [N]
ELSIZE=0.5				! velikost prvku [mm]

*dim,T_matrix,array,12	! import externe vypoctenych hodnot tloustky odpovidajicich hodnotam uhlu alfa pro danou modifikaci
T_matrix(1,1)=1.617, 1.726, 1.824, 1.909, 1.982, 2.040, 2.083, 2.110	

T=T_matrix(step,1)		! automaticky vyber tloustky, ktera odpovida uhlu alfa nastavenemu v dany okamzik


SELTOL,1e-6				! automaticke nastaveni potrebnych parametru
L=LH*H

!!! Definice elementu !!!
!ET,1,SOLID186
ET,1,SOLID187

!!! Definice materialu !!!
MP,EX,1,Emod
MP,PRXY,1,,nu

!!! Tvorba geometrie !!!
	
	!!! Referencni geometrie !!!
!K,10,H-L*cos(alfa),0,0
!K,20,H,L*sin(alfa),0
!K,30,0,L*sin(alfa),0

!L,10,20	$	L,20,30

	!!! Vnitrni geometrie !!!
K,1,H-L*cos(alfa)-T/(2*cos(90-alfa))+T/(2*tan(alfa)),0,0
K,12,H-L*cos(alfa)-T/(2*cos(90-alfa))+T/(2*tan(alfa)),T/2,0
K,2,H-T/2*(cos(alfa/2)/sin(alfa/2)),L*sin(alfa)-T/2,0
K,3,0,L*sin(alfa)-T/2,0

L,1,12	$	L,12,2	$	L,2,3	

	!!! Vnejsi geometrie !!!
!K,11,H-L*cos(alfa)+T/(2*cos(90-alfa)),0,0
K,11,H-L*cos(alfa)+T/(2*tan(alfa/2)),T/2,0
K,1122,H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa)-T/2*tan(90-alfa),L*sin(alfa)-T/2,0
K,22,H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa)-T/2*tan(90-alfa),L*sin(alfa),0
K,33,0,L*sin(alfa),0
K,111,H-L*cos(alfa),0,0
K,41,2*H-L*cos(alfa),T/2,0
K,44,2*H-L*cos(alfa),0,0							

L,11,1122	$	L,1122,22	$	L,22,33	

L,1,111	$	L,111,44	$	L,44,41	$	L,41,11	$	L,3,33

	!!! Vytvoreni plochy !!!
LSEL,ALL
LPLOT
AL,ALL

!ARSYM,X,ALL,,,,1,0
!ASEL,ALL
!ARSYM,Y,ALL,,,,1,0
!ASEL,ALL

!AADD,ALL

!!! Vytvoreni objemu 1 !!!
VEXT,ALL,,,,,T/2

!!! Rotace objemu 1 !!!
! Definice lokalniho SS pro rotaci !
K,1000,0,T/4,T/4
K,2000,0,T/4,T/4+1
K,3000,0,T/4+1,T/4+1
NKPT,1,1000
NKPT,2,2000
NKPT,3,3000
CS,11,1,1,2,3
! Rotace !
VSEL,ALL
VGEN,2,ALL,,,0,-90,0
CSYS,0

!!! Rotace objemu 2 !!!
! Definice lokalniho SS pro rotaci !
K,4000,H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa)-T/2*tan(90-alfa),L*sin(alfa)-T/4,T/4
K,5000,H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa)-T/2*tan(90-alfa),L*sin(alfa)-T/4,T/4+1
K,6000,H+T/2*(cos(alfa/2)/sin(alfa/2))-T*tan(90-alfa),L*sin(alfa)-T/2,T/4
NKPT,4,4000
NKPT,5,5000
NKPT,6,6000
CS,12,1,4,5,6
! Rotace !
VSEL,S,VOLU,,1
VGEN,2,ALL,,,0,-90,0
VSEL,ALL
CSYS,0

!!! Rotace objemu 3 !!!
! Definice lokalniho SS pro rotaci !
K,7000,2*H-L*cos(alfa),L*sin(alfa)-T/4,L*sin(alfa)-T/4
K,8000,2*H-L*cos(alfa),L*sin(alfa)-T/4,L*sin(alfa)-T/4+1
K,9000,2*H-L*cos(alfa),L*sin(alfa)-T/4-1,L*sin(alfa)-T/4+1
NKPT,7,7000
NKPT,8,8000
NKPT,9,9000
CS,13,1,7,8,9
! Rotace !
VSEL,S,VOLU,,3
VGEN,2,ALL,,,0,-90,0
VSEL,ALL
CSYS,0

!!! Vytvoreni SS pro korelaci s analytickym modelem !!!
K,10000,0,0,0
K,11000,0,0,1
K,12000,0,-1,1
NKPT,10,10000
NKPT,11,11000
NKPT,12,12000
CS,14,0,10,11,12

CSYS,0

!!! Odstraneni pomocnych uzlu !!!
NSEL,S,NODE,,1,12,1
NDELE,ALL

!!! Spojeni do jednoho objemu !!!
VSEL,ALL
VADD,ALL


!!! Vytvoreni site !!!
VSEL,ALL
ESIZE,ELSIZE
VATT,1,,1
VMESH,ALL

NUMMRG,NODE,0.000001
NUMMRG,KP,0.000001

NSEL,ALL
*GET,maxnode1,NODE,0,NUM,MAX


!!! Okrajove podminky !!!
NSEL,S,LOC,Z,0					$	D,ALL,UZ,0
NSEL,S,LOC,Y,0					$	D,ALL,UY,0
NSEL,S,LOC,X,0					$	D,ALL,UX,0
NSEL,S,LOC,Z,L*sin(alfa)		$	CP,1,UZ,ALL
NSEL,S,LOC,X,2*H-L*cos(alfa)	$	CP,2,UX,ALL
NSEL,S,LOC,Y,L*sin(alfa)		$	CP,3,UY,ALL

!!! Zatizeni !!!
NSEL,S,LOC,Z,L*sin(alfa)	$	NSEL,R,LOC,X,0	$	NSEL,R,LOC,Y,0
F,ALL,FZ,Fappl/4

ALLSEL,ALL

!!!!!!!!!!!!!!!!
!!! SOLUTION !!!
!!!!!!!!!!!!!!!!

/SOLU
	
SOLVE


!!!!!!!!!!!!!!!!!!!!!
!!! POSTPROCESSOR !!!
!!!!!!!!!!!!!!!!!!!!!

/POST1

CSYS,14

!!! Zjisteni posuvu ve smeru Z !!!
NSEL,S,LOC,Z,2*H-L*cos(alfa)
*GET,minnode1,NODE,0,NUM,MIN
*GET,UZdisp,NODE,minnode1,U,X

!!! Zjisteni posuvu ve smeru X !!!
NSEL,S,LOC,X,L*sin(alfa)	
*GET,minnode2,NODE,0,NUM,MIN
*GET,UXdisp,NODE,minnode2,U,Z

!!! Zjisteni posuvu ve smeru y !!!
NSEL,S,LOC,Y,-L*sin(alfa)
*GET,minnode3,NODE,0,NUM,MIN
*GET,UYdisp,NODE,minnode3,U,Y

!!! Vypocet Poissonova pomeru v pricnem smeru z !!!
Z0=2*H-L*cos(alfa)
X0=L*sin(alfa)

epsX=UXdisp/X0
epsZ=UZdisp/Z0

nuCALCxz=-epsZ/epsX

!!! Vypocet Poissonova pomeru v pricnem smeru y !!!
X0=L*sin(alfa)
Y0=L*sin(alfa)

epsY=UYdisp/Y0
epsX=UXdisp/X0

nuCALCxy=-epsY/epsX

!!! Urceni plochy bunek !!!
S=(2*H-L*cos(alfa))*(L*sin(alfa))

!!! Vypocet Ex !!!
sigma=(Fappl/4)/S
EcalcX=abs(sigma/epsX)/Emod


!!!!!!!!!!!!!!!!!!!!!!!
!!! Export výsledků !!!
!!!!!!!!!!!!!!!!!!!!!!!

*CFOPEN,vysledky_nuCALCxz,txt,,APPEND
*VWRITE,nuCALCxz
(1F12.6)
*CFCLOS

*CFOPEN,vysledky_nuCALCxy,txt,,APPEND
*VWRITE,nuCALCxy
(1F12.6)
*CFCLOS

*CFOPEN,vysledky_EcalcX,txt,,APPEND
*VWRITE,EcalcX
(1F15.12)
*CFCLOS


/clear

*ENDDO

*ABBR,INPUT,'/INPUT,strukturaC_linear_X,txt'  













